# Copyright 2018 The Hafnium Authors.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

config("gtest_config") {
  visibility = [ ":gtest" ]

  include_dirs = [
    "googletest/googletest/include",
    "googletest/googlemock/include",
  ]

  ldflags = [ "-pthread" ]
}

source_set("gtest") {
  testonly = true

  sources = [
    "googletest/googlemock/src/gmock-all.cc",
    "googletest/googletest/src/gtest-all.cc",
  ]

  include_dirs = [
    "googletest/googletest",
    "googletest/googlemock",
  ]

  all_dependent_configs = [ ":gtest_config" ]
}

source_set("gtest_main") {
  testonly = true

  sources = [
    "googletest/googlemock/src/gmock_main.cc",
  ]

  deps = [
    ":gtest",
  ]
}

action("linux_defconfig") {
  script = "//build/make.py"
  args = [
    "--directory",
    rebase_path("linux"),
    "--out_file",
    ".config",
    "--copy_out_file",
    rebase_path("${target_out_dir}/.config"),
    "CC=" + rebase_path("//prebuilts/linux-x64/clang/bin/clang"),
    "ARCH=arm64",
    "CROSS_COMPILE=aarch64-linux-gnu-",
    "-j24",
    "defconfig",
    "modules_prepare",
  ]
  outputs = [
    # We don't actually care about this, but GN requires us to have some output.
    "${target_out_dir}/.config",
  ]
}

action("linux") {
  script = "//build/make.py"
  args = [
    "--directory",
    rebase_path("linux"),
    "--out_file",
    "arch/arm64/boot/Image",
    "--copy_out_file",
    rebase_path("${target_out_dir}/linux.bin"),
    "CC=" + rebase_path("//prebuilts/linux-x64/clang/bin/clang"),
    "ARCH=arm64",
    "CROSS_COMPILE=aarch64-linux-gnu-",
    "-j24",
  ]
  outputs = [
    "${target_out_dir}/linux.bin",
  ]
  deps = [
    ":linux_defconfig",
  ]
}